* RFE3View 3.0 - reference-phase analysis
* Field Precision LLC, Copyright 2010
*
* Value of a complex quantity at the reference phase phi0:
*   Q = Qr*cos(phi0) - Qi*sin(phi0)
*
* Variables
*   &PhiR, &PhiI, &ExR, &ExI, &EyR, &EyI, &EzR, &EzI, &EMag, &Q[N]
* Stored quantities
*   PhiReal  Real particle of the quasi-static potential (V)
*   PhiImag  Imaginary particle of the quasi-static potential (V)
*   EpsiR    Relative permitivity
*   Sigma    Electrical conductivity (S/m)
*   PDens    Time-averaged power density (J/m3)

HEADER
  ProgramName = RFE3View 3.0
  ManualName = rfe3.pdf
  WebSiteURL = http://www.fieldp.com
  DataSuffix = ROU
  About = RFE3View 3.0;Copyright 2010;Field Precision LLC;Albuquerque, NM USA
  NRecord = 5
  SliceDisplay = 1
  ScanDisplay = 1
  VectorDisplay = 1
  PlaneDisplay = 1
  SurfaceDisplay = 1
END

STOREDQUANT
  PhiR N
  PhiI N
  Epsi E
  Sigma E
  PDens E
END

REGIONQUANT
END

PROGPARAM
  $DegToRad = 0.0174533
  $Epsi0 = 8.854187E-12
  $TwoPi = 6.283185
END

RUNPARAM
  $Freq = 0.0
END

REALTIMEPARAM
  $Phi0 = 0.0
END

INTERPOLATION

* Potential
  PhiRef = $Phi0 $DegToRad * @ENTER @COS &PhiR * @EXCH @SIN &PhiI * -

* Electric field
  ExRef = $Phi0 $DegToRad * @ENTER @COS &ExR * @EXCH @SIN &ExI * -
  EyRef = $Phi0 $DegToRad * @ENTER @COS &EyR * @EXCH @SIN &EyI * -
  EzRef = $Phi0 $DegToRad * @ENTER @COS &EzR * @EXCH @SIN &EzI * -
  EMagRef = $Phi0 $DegToRad * @ENTER @COS &ExR * @EXCH @SIN &ExI * - 2 ^ $Phi0 $DegToRad * @ENTER @COS &EyR * @EXCH @SIN &EyI * - 2 ^ + $Phi0 $DegToRad * @ENTER @COS &EzR * @EXCH @SIN &EzI * - 2 ^ + @SQRT

* Material properties
  EpsiR = &Q[3]
  Sigma = &Q[4]

* Conductive current: [Sigma*Er, Sigma*Ei]
  JcxRef = $Phi0 $DegToRad * @ENTER @COS &ExR * @EXCH @SIN &ExI * - &Q[4] *
  JcyRef = $Phi0 $DegToRad * @ENTER @COS &EyR * @EXCH @SIN &EyI * - &Q[4] *
  JczRef = $Phi0 $DegToRad * @ENTER @COS &EzR * @EXCH @SIN &EzI * - &Q[4] *
  JcMagRef = $Phi0 $DegToRad * @ENTER @COS &ExR * @EXCH @SIN &ExI * - 2 ^ $Phi0 $DegToRad * @ENTER @COS &EyR * @EXCH @SIN &EyI * - 2 ^ + $Phi0 $DegToRad * @ENTER @COS &EzR * @EXCH @SIN &EzI * - 2 ^ + @SQRT
  JcMagRef = $Phi0 $DegToRad * @ENTER @COS &ExR * @EXCH @SIN &ExI * - 2 ^ $Phi0 $DegToRad * @ENTER @COS &EyR * @EXCH @SIN &EyI * - 2 ^ + $Phi0 $DegToRad * @ENTER @COS &EzR * @EXCH @SIN &EzI * - 2 ^ +  @SQRT &Q[4] *

* Displacement current: [-2*pi*Freq*Epsi0*EpsiR*Ei,2*pi*Freq*Epsi0*EpsiR*Er]
  JdxRef = $Phi0 $DegToRad * @ENTER @COS &ExI * @EXCH @SIN &ExR * + $TwoPi * $Freq * $Epsi0 * &Q[3] *
  JdyRef = $Phi0 $DegToRad * @ENTER @COS &EyI * @EXCH @SIN &EyR * + $TwoPi * $Freq * $Epsi0 * &Q[3] *
  JdzRef = $Phi0 $DegToRad * @ENTER @COS &EzI * @EXCH @SIN &EzR * + $TwoPi * $Freq * $Epsi0 * &Q[3] *
  JdMagRef = $Phi0 $DegToRad * @ENTER @COS &ExI * @EXCH @SIN &ExR * + 2 ^ $Phi0 $DegToRad * @ENTER @COS &EyI * @EXCH @SIN &EyR * + 2 ^ + $Phi0 $DegToRad * @ENTER @COS &EzI * @EXCH @SIN &EzR * + 2 ^ + @SQRT $TwoPi * $Freq * $Epsi0 * &Q[3] *
END

VECTOR
* Vector display of electric field direction
  EVect = $Phi0 $DegToRad * @ENTER @COS &ExR * @EXCH @SIN &ExI * -;$Phi0 $DegToRad * @ENTER @COS &EyR * @EXCH @SIN &EyI * -;$Phi0 $DegToRad * @ENTER @COS &EzR * @EXCH @SIN &EzI * -
END

VOLUME
END

SURFACE
END

ENDFILE